Path: ibmpcug!wendy.ibmpcug.co.uk!pipex!howland.reston.ans.net!Germany.EU.net!EU.net!news.eunet.fi!uuno.reka.fi!jpo
From: Juha Pohjalainen <jpo@uuno.reka.fi>
Newsgroups: rec.games.corewar
Subject: Closing hills - sources found
Date: Thu, 18 May 1995 08:56:21 +0200
Lines: 253
Message-ID: <Pine.HPP.3.91.950518085421.27725A-100000@uuno.reka.fi>
References: <HAN.95May16125401@banaba.imag.fr>
NNTP-Posting-Host: uuno.reka.fi
Mime-Version: 1.0
Content-Type: TEXT/PLAIN; charset=US-ASCII
In-Reply-To: <HAN.95May16125401@banaba.imag.fr> 


Because I got my lost warriors back from KOTH server, I decided to
share these with you. These are The Original Ones! Enjoy!

Thank you to KOTH personnel for job well done.

----------------------------------------------------------------------------
  E-Mail ... jippo@clinet.fi            In Real World ... Juha Pohjalainen
             Juha.Pohjalainen@reka.fi   Nickname ........ Jippo
----------------------------------------------------------------------------

;Address jippo@clinet.fi
;redcode-94
;name Silk Warrior 1.3
;author J.Pohjalainen
;strategy Silk Warrior   ( Paper - The Next Generation )
;strategy ==============================================
;strategy v1.0: only one tiny paper
;strategy v1.1: made it bigger and maybe more lethal
;strategy v1.2: better distribution (starts as a mod-40)
;strategy       now kills previous copies and does some
;strategy       selftesting
;strategy v1.3: bigger and more lethal, I hope
;kill
;assert CORESIZE==8000
 
STEP    equ     2364
SIZE    equ     12
 
warrior
 
        spl     1,          <-98
        mov     -1,         0
        spl     1,          <-99
 
paper   spl     @paper,     STEP
        mov.i   }paper,     >paper
        mov.i   gate,       >paper
        mov.i   gate,       {-5*SIZE-1
        mov.i   gate,       {4000
silk    jmp     @silk,      {paper
gate    dat.f   <2667,      <2*2667
 
end warrior                                   

---

;Address jippo@clinet.fi
;redcode-94 verbose
;name Phoenix 1.1
;author J.Pohjalainen
;strategy v1.0: some kind of a replicator, but now same code
;strategy       executed once (so, maybe it is not true paper)
;strategy v1.1: some more code and different constants
;kill Phoenix
;assert CORESIZE==8000
 
PSTEP   equ     3520
NSTEP   equ     1520
ESTEP   equ      830
 
warrior
        spl     1,          <-98
        mov.i   -1,         0
        mov.i   -1,         0
        mov.i   -1,         0
 
phoenix spl     @phoenix,   PSTEP
        mov.i   }phoenix,   >phoenix
nest    spl     @nest,      NSTEP
        mov.i   }nest,      >nest
egg     spl     @egg,       ESTEP
        mov.i   }egg,       >egg
        mov.i   ash,        {3999
        mov.i   ash,        }4001
ash     dat.f   <2667,      <2*2667
        dat.f   <2667,      <2*2667
        dat.f   <2667,      <2*2667
        dat.f   <2667,      <2*2667
        dat.f   <2667,      <2*2667
 
end warrior                                   

---

;Address jippo@clinet.fi
;redcode-94 verbose
;name TimeScape (1.0)
;author J. Pohjalainen
;assert CORESIZE==8000
;strategy I'm stuck with replicators! Here is _The Latest_ one!
;strategy \---------------------------\  ----------------------
;strategy / ts1  spl    @ts1,  }STEP1 /  Phoenix/Cell   warrior  
;strategy \      mov.i  }ts1,  >ts1   \  body,  6+ processes to 
;strategy / ts2  spl    @ts2,  }STEP2 /  keep That Thing alive,
;strategy \      mov.i  }ts2,  >ts2   \  two  of  them  working   
;strategy /      mov.i  {ts2,  <ts3   /  together  with  proper  
;strategy \ ts3  jmp    @ts3,  }STEP3 \  constants and you have
;strategy /___________________________/  found >>--> TimeScape!   
;strategy \T I M E   T O   E S C A P E\  ----------------------
;strategy v1.0: added more havoc in above code  (or I hope so!)
;kill TimeScape

TSTEP equ 1800
CSTEP equ 3740
NSTEP equ -1922
FSTEP equ 1870

tim1    spl     @tim1,          }TSTEP
        mov.i   }tim1,          >tim1
cel1    spl     @cel1,          }CSTEP
        mov.i   }cel1,          >cel1
        mov.i   {-FSTEP,        <FSTEP
        mov.i   {cel1,          <ncl1
ncl1    jmp     @ncl1,          >NSTEP

st for 82
        dat.f   0,              0
rof

warrior

        spl     1,              <-200
        spl     1,              <-300
        mov.i   -1,             0

        spl     tim1,           <-400

tim2    spl     @tim2,          }TSTEP
        mov.i   }tim2,          >tim2
cel2    spl     @cel2,          }CSTEP
        mov.i   }cel2,          >cel2
        mov.i   <-FSTEP,        {FSTEP
        mov.i   {cel2,          <ncl2
ncl2    jmp     @ncl2,          >NSTEP

end warrior

---

;Address jippo@clinet.fi
;redcode-94x
;name Big Silk Warrior 1.0
;author J.Pohjalainen
;strategy v1.0: trying paper on big hill
;assert CORESIZE==55440
;macro

STEP    equ     16120

warrior
        spl     1,          <-198
        mov     -1,         0
        spl     1,          <-199

paper   spl     @paper,     >STEP
        mov.i   }paper,     >paper
        mov.i   gate,       }27720
        mov.i   gate,       >27720
        mov.i   gate,       >paper
silk    jmp     @silk,      {paper
gate    dat.f   <34117,     <35873

end warrior

---

;Address jippo@clinet.fi
;redcode-94x verbose
;name Big Phoenix 1.0
;author J.Pohjalainen
;strategy v1.0: some kind of a replicator, but now same code
;strategy       executed once (so, maybe it is not true paper)
;strategy       Big Hill version
;assert CORESIZE==55440
 
STEP1   equ     21440
STEP2   equ     10300
STEP3   equ      3550
 
warrior
        spl     1,          <-197
        spl     1,          <-198
        spl     1,          <-199
 
phoe1   spl     @phoe1,     STEP1
        mov.i   }phoe1,     >phoe1
phoe2   spl     @phoe2,     STEP2
        mov.i   }phoe2,     >phoe2
phoe3   spl     @phoe3,     STEP3
        mov.i   }phoe3,     >phoe3
        mov.i   egg,        }27721
egg     dat.f   <34117,     <35873
        dat.f   <34117,     <35873
        dat.f   <34117,     <35873
        dat.f   <34117,     <35873
        dat.f   <34117,     <35873
end warrior                                   
 
---

;Address jippo@clinet.fi
;redcode-94x verbose
;name TimeScapeX (0.1)
;author J. Pohjalainen
;assert CORESIZE==55440
;strategy I'm stuck with replicators! Here is _The Latest_ one!
;strategy \---------------------------\  ----------------------
;strategy / ts1  spl    @ts1,  }STEP1 /  Phoenix/Cell   warrior  
;strategy \      mov.i  }ts1,  >ts1   \  body,  6+ processes to 
;strategy / ts2  spl    @ts2,  }STEP2 /  keep That Thing alive,
;strategy \      mov.i  }ts2,  >ts2   \  two  of  them  working   
;strategy /      mov.i  {ts2,  <ts3   /  together  with  proper  
;strategy \ ts3  jmp    @ts3,  }STEP3 \  constants and you have
;strategy /___________________________/  found >>-> TimeScapeX!   
;strategy \T I M E   T O   E S C A P E\  ----------------------
;kill TimeScape

TSTEP equ 24000
CSTEP equ 19020
NSTEP equ -9714

tim1    spl     @tim1,          }TSTEP
        mov.i   }tim1,          >tim1
cel1    spl     @cel1,          }CSTEP
        mov.i   }cel1,          >cel1
        mov.i   {cel1,          <ncl1
ncl1    jmp     @ncl1,          >NSTEP

st for 184
        dat.f   0,              0
rof

warrior

        spl     1,              <-200
        mov.i   -1,             0
        spl     1,              <-300

        spl     tim1,           <-400

tim2    spl     @tim2,          }TSTEP
        mov.i   }tim2,          >tim2
cel2    spl     @cel2,          }CSTEP
        mov.i   }cel2,          >cel2
        mov.i   {cel2,          <ncl2
ncl2    jmp     @ncl2,          >NSTEP

end warrior